// second attempt at prop. while the first works okay, am wondering
// if copying a modern design will be better still. Not that this is a good copy of a modern design.
// Could do with concave surfaces.
// This version is also keyed for the end of the shaft.
// wouldnt be good with a reverse, but we don't currently have a reverse capable speed controller...

// this is orientated for printing, so the active surfaces face up, away from the supports.

// original best was 34mm dia, 30 degree pitch (that is, 30 degrees from
// having no pitch at all).

// trying out on the water, 2 blades, 36mm dia, 30 degree pitch was a little too much for S3, warm motor
// 2 blades, 34mm dia, 30 degree pitch was good, cool motor and planing speed
// 3 blades, 34mm dia, 30 degree pitch appeared to have the same speed but warmer motor.

// considering there is a ~5 degree down angle on the prop, and the boat leans back when on the plane, 
// there is a fair amount of water jumping into the air behind the boat.

blades=2;
diameter=34;  // 36mm is closer to the maximum, 40mm would be too much with it
                         // also being further along the drive shaft.
                        

drivedia=5;   // hole in hub
keydia=5.5;  // slightly larger shaft dia, so that the section that cant be drilled will still fit the shaft
keylen=4.5;
keyoffset=1.5;  // mm from center
hubdia=8;      // out hub diameter
halfdia=(hubdia+drivedia)/2;
hublenback=15;
hublenfront=1;

attackang=30;

bladethickness=1.3;
bladetipthickness=0.8;

bladelength=15;

$fn=50;

dr=0.25;

//function  bladelen(s) = s<bladelength*0.75?(1/0.75)*(diameter/2-halfdia/2)*(s)/bladelength:diameter/2-halfdia/2;
function  bladelen(s) = diameter/2-halfdia/2;

difference()
 {   
     union()
      {
        translate([0,0,-hublenfront])
            cylinder(hublenback+hublenfront,hubdia/2,hubdia/2);  // hub
        translate([0,0,-hublenfront-(hubdia-drivedia)])
            cylinder(hubdia-drivedia,drivedia/2,hubdia/2);   // slope on front of hub
          
        for(b=[0:360/blades:360])
            rotate([0,0,b])
            for(s=[0:dr:bladelength-dr])
                hull()
                  {
                      translate([0,0,s*sin(attackang)])
                          rotate([0,0, 360*s*cos(attackang)/(3.142*diameter) ])
                              translate([halfdia/2,0,0])
                                   rotate([0,90,0])
                                       cylinder( bladelen(s),bladethickness/2,bladetipthickness/2);
                        translate([0,0,(s+dr)*sin(attackang)])
                           rotate([0,0, 360*(s+dr)*cos(attackang)/(3.142*diameter) ])
                               translate([halfdia/2,0,0])
                                  rotate([0,90,0])
                                     cylinder( bladelen(s+dr),bladethickness/2,bladetipthickness/2);
                }
            }

    union()
      {
        translate([0,0,-hublenfront-(hubdia-drivedia)-0.5])  // subtract drive shaft
           cylinder(hublenback+hublenfront+1,drivedia/2,drivedia/2);
          translate([0,0,hublenback-keylen])  // subtract slightly more from back, so that it will fit the shaft
            cylinder(keylen+1,keydia/2,keydia/2);
      }
 }

intersection()
  {    
      translate([0,0,-hublenfront])
           cylinder(hublenback+hublenfront,hubdia/2,hubdia/2);  // hub
      hull()
       {
         translate([-hubdia/2,keyoffset,hublenback-keylen])   // main key
             cube([hubdia,hubdia,keylen]);
         translate([-hubdia/2,keyoffset+keyoffset,hublenback-keylen-keyoffset])  // slope on key, to avoid supports
             cube([hubdia,hubdia,keylen]);
       }
  }